home *** CD-ROM | disk | FTP | other *** search
/ Windows Expert / Windows Expert.iso / business / pcprojct.zip / PROJECT.ZOO / act / proj.act next >
Text File  |  1990-04-14  |  7KB  |  269 lines
  1. /* proj.act       --miscelaneous methods, initializations
  2. */
  3.  
  4. /* globals for application colors */
  5. Actor[#CritColor]:=RED;
  6. Actor[#SlackColor]:=BLUE;
  7. !!
  8.  
  9. /* globals for conditional compilation during debugging etc */
  10.  
  11. Actor[#Debug] := false;     /* debugging enable/disable */
  12. Actor[#Trace] := false;     /* trace recalc calls */      
  13. Actor[#CurPos] := 0;        /* text dump of network uses this */ 
  14. !!
  15.  
  16. /* methods for system classes */
  17.  
  18. now(Window)!!
  19.  
  20. /* Set the current cursor position in client coords.
  21.    This is useful when implementing a keyboard interface. */
  22. Def  setCursorPos(self, pos | scrnPos)
  23. { 
  24.   scrnPos := clientToScreen(self, pos);
  25.   Call SetCursorPos(scrnPos.x, scrnPos.y);
  26. }!!
  27.  
  28. /* Return a point of the current cursor position in client coords.
  29.    This is useful when implementing a keyboard interface. */
  30. Def  getCursorPos(self | struct, scrnPos, lpr)
  31. { 
  32.   struct := new(Struct,4);          /* to store the point */
  33.   lpr := lP(struct);                /* long pointer */
  34.   Call GetCursorPos(lpr);           /* device coords */
  35.   scrnPos := pointAt(lpr);          /* get the data */
  36.   freeHandle(struct);               /* free up memory */
  37.   ^screenToClient(self, scrnPos);   /* screen coords */
  38. }!!
  39.  
  40. /* Return a point giving the text width and height
  41.    in the given display context. 
  42.    e.g. for system font the return value might be 
  43.    8@15 for 8 pixels wide, 15 high, depending on the
  44.    Windows drivers. */
  45. Def  textSize(self, hDC | tm1, tm2)
  46. { 
  47.   tm1 := new(Struct, 31);            /* to hold the info */
  48.   Call GetTextMetrics(hDC, lP(tm1)); /* call Windows fn */
  49.   tm2 := getData(tm1);               /* get the data back */
  50.   freeHandle(tm1);                   /* free up memory */
  51.   ^point(low(tm2[10]), low(tm2[0])); /* width@height */
  52. }!!
  53.  
  54.  
  55. now(TextWindow)!!
  56.  
  57. /* Print a line in a TextWindow. */
  58. Def printLine(self, str)
  59. {
  60.   printString(self, str);
  61.   eol(self);
  62. }!!
  63.  
  64.  
  65. now(Dialog);!!
  66.  
  67. /* Run the dialog with the appropriate resource
  68.    and parent.  Display a warning if it fails. */
  69. Def  checkRunModal(self, res, parent | retValue)
  70. {
  71.   retValue := runModal(self, res, parent);
  72.   if retValue == NOMEM
  73.     beep();
  74.     errorBox(loadString(PW_WARNING),
  75.              loadString(PW_ERRMEM1) + CR_LF +
  76.              loadString(PW_ERRMEM2));
  77.   endif;
  78.   ^retValue;
  79. }!!
  80.  
  81. now(String);!!
  82.  
  83. /* Return the string in a field of fieldSize.
  84.    Truncate or pad with blanks as necessary.
  85. */
  86. Def  field(self, fieldSize | size)
  87. {
  88.   if fieldSize < size := size(self)
  89.     ^subString(self, 0, fieldSize)            /* truncate */
  90.   else
  91.     ^self + stringOf(' ', fieldSize - size);  /* pad */
  92.   endif;
  93. }!!
  94.  
  95. /* Convert to decimal.  Safe if length = 0. */
  96. Def  asDec(self)
  97. {
  98.   if size(self) = 0
  99.     ^ 0;
  100.   else
  101.     ^asInt(self,10);
  102.   endif;
  103. }!!
  104.  
  105. /* Show a yesNoBox with self as the caption, str as message.  
  106.    Return value of 6 = IDYES, 7 = IDNO. */
  107. Def yesNoBox(self, str)
  108. {  ^new(ErrorBox, ThePort, str, self, 4);
  109. }!!
  110.  
  111. /* Convert a string into a Date object.
  112.    Use the international string format.  
  113.    Return nil if not a valid date. */
  114. Def asIntlDate(self | sep, format, ints, posn, pos1, pos2, mm, dd, yy)
  115. { sep := getProfileString(System, "intl", "sDate");
  116.   if sep = "" then sep := "/"; endif;
  117.   format := getProfileString(System, "intl", "iDate");
  118.   select
  119.     case format = "2"
  120.       posn := #(2 0 1); /* YYMMDD */
  121.     endCase
  122.     case format = "1"
  123.       posn := #(1 0 2); /* DDMMYY */
  124.     endCase
  125.     default       
  126.       posn := #(0 1 2); /* MMDDYY */
  127.   endSelect;
  128.   ints := new(Array, 3);
  129.   pos1 := find(self, sep, 0);
  130.   if not(pos1) ^nil; endif;
  131.   ints[0] := asDec(subString(self, 0, pos1));  
  132.   pos2 := find(self, sep, pos1+1);
  133.   if not(pos2) ^nil; endif;
  134.   ints[1] := asDec(subString(self, pos1+1, pos2));
  135.   ints[2] := asDec(subString(self, pos2+1, size(self)));
  136.   mm := ints[posn[0]];  dd := ints[posn[1]];  yy := ints[posn[2]];
  137.   if not(mm) cor mm > 12 cor mm < 1 ^nil; endif;
  138.   if not(dd) cor dd > 31 cor dd < 1 ^nil; endif;
  139.   if not(yy) cor yy < 0 ^nil; endif;
  140.   if yy < 100 yy := yy + 1900; endif;
  141.   ^date(mm, dd, yy);
  142. }!!
  143.  
  144. /* Report an error if the date string is invalid,
  145.    otherwise return the Date object.  Ignore empty strings.
  146.    Report the error according to international date format. */
  147. Def  checkDate(self | retValue, iDate, format)
  148. { 
  149.   if self <> ""
  150.   cand not(retValue := asIntlDate(self))
  151.     beep();
  152.     iDate := getProfileString(System, "intl", "iDate");
  153.     select
  154.       case iDate = "2"
  155.         format := loadString(PW_YYMMDD);
  156.       endCase
  157.       case iDate = "1"
  158.         format := loadString(PW_DDMMYY);
  159.       endCase
  160.       default                               /* "0" or unspecified */
  161.         format := loadString(PW_MMDDYY);
  162.     endSelect;
  163.     errorBox(loadString(PW_ERRDATE1),
  164.              asString(self) + loadString(PW_ERRDATE2) + format +
  165.              loadString(PW_ERRDATE3));
  166.   endif;
  167.   ^retValue;
  168. }!!
  169.  
  170.  
  171. now(Date)!!
  172.  
  173. /* Modify the asString method to use intl format. */
  174. Def asString(self)
  175. {
  176.   ^asIntlString(self);
  177. }!!
  178.  
  179. /* Convert a date to a string.  NilClass:checkString
  180.    returns an empty string. */
  181. Def  checkString(self)
  182. { 
  183.   ^asString(self);
  184. }!!
  185.  
  186.  
  187. /* Return date in international string format. 
  188.    Abbreviate the year.  */
  189. Def asIntlString(self | sep, form, da, yr)
  190. { 
  191.   sep := getProfileString(System, "intl", "sDate");
  192.   if sep = "" sep := "/"; endif;
  193.   form := getProfileString(System, "intl", "iDate");
  194.   da := asDateArray(self); 
  195.   if da[2] > 1900
  196.     yr := subString(asString(da[2]), 2, 4);
  197.   else
  198.     yr := asString(da[2]);
  199.   endif;
  200.   select
  201.     case form = "2" /* YYMMDD */
  202.      ^yr+sep+asString(da[1])+sep+asString(da[0]);
  203.     endCase
  204.     case form = "1" /* DDMMYY */
  205.      ^asString(da[1])+sep+asString(da[0])+sep+yr;
  206.     endCase
  207.     default         /* MMDDYY */
  208.      ^asString(da[0])+sep+asString(da[1])+sep+yr;
  209.     endSelect;
  210. }!!
  211.  
  212.  
  213. now(Int)!!
  214.  
  215. /* Create a date object with a starting value. */
  216. Def date(self, dd, yy)
  217. {
  218.   ^date(new(Date), self, dd, yy);
  219. }!!
  220.  
  221.  
  222. now(NilObject)!!
  223.  
  224. /* Return an empty string.  For compatibility
  225.    with the Date class so you can checkString(nil)
  226.    or checkString(aDate) and get a string. */
  227. Def  checkString(self)
  228. { 
  229.   ^"";
  230. }!!
  231.  
  232.  
  233. now(Collection)!!
  234.  
  235. /* Returns true (the position) if the elem is in the collection.
  236.    Uses a sequential search.  Descendent classes redefine this
  237.    using more efficient means where possible. */
  238. Def  in(self, elem)
  239. {
  240.   do(size(self),
  241.     {using(i) 
  242.      if self[i] = elem ^i; endif;   /* found */
  243.   });
  244.   ^false;    /* not found */
  245. }!!
  246.  
  247.  
  248. now(Dictionary)!!
  249.  
  250. /* Returns the value (true) if the key is in the Dictionary. */
  251. Def  in(self, key | assoc)
  252. {
  253.   assoc := assocAt(self, key);
  254.   if assoc
  255.     ^assoc.value;
  256.   else
  257.     ^false;
  258.   endif;
  259. }!!
  260.  
  261. now(Object)!!
  262. /* This method overrides the default case of objects not being
  263.    storable so that Project, Milestone, Task etc are all storable.
  264. */
  265. Def notStorable(self)
  266. {
  267.   ^nil;
  268. }!!
  269.